I had a question asked of me relating to how one could change the viewed page of an actively open PDF through VBA and that got me curious.

The concept is pretty straightforward, in the sense, that you need to identify the textbox in Adobe that you need to update once you know that, you can use APIs to locate it, update it’s value, …

I’m too stubborn to let it go, so last night I figured it out.  The heart of the process is a very simple procedure

'---------------------------------------------------------------------------------------
' Procedure : ChangePDFPage
' Author    : Daniel Pineault, CARDA Consultants Inc.
' Website   : http://www.cardaconsultants.com
' Purpose   : Change the page of a Adobe Reader PDF
' Copyright : The following is release as Attribution-ShareAlike 4.0 International
'             (CC BY-SA 4.0) - https://creativecommons.org/licenses/by-sa/4.0/
' Req'd Refs: Uses Late Binding, so none required
'
' Input Variables:
' ~~~~~~~~~~~~~~~~
' sFile     : Fully qualified path, filename & extension of the PDF file
' lPage     : Page number to view
'
' Usage:
' ~~~~~~
' Call ChangePDFPage("C:\Users\Daniel\Documents\AccessTechniques.pdf", 65)
'
' Revision History:
' Rev       Date(yyyy/mm/dd)        Description
' **************************************************************************************
' 1         2018-11-25              Initial Release
'---------------------------------------------------------------------------------------
Public Function ChangePDFPage(sFile As String, lPage As Long)
    Dim hwndParent&
    Dim hwndChild&
    Dim sFileName             As String

    On Error GoTo Error_Handler

    sFileName = Right(sFile, Len(sFile) - InStrRev(sFile, "\"))    'Get just the filename from the full path/filename/ext
    hwndParent = FindChildWindow(FnFindWindowLike("*" & sFileName & "* - Adobe*"), "AVL_AVView", "AVTopBarView", True)
    If hwndParent = 0 Then
        'This means that we can't find an instance of Adobe with the specified File, so we could use the traditional approach for the first time
        Call OpenPDF(sFile, lPage)
    Else
        hwndChild = GetWindow(hwndParent, GW_CHILD)        'Find the 1st Child window handle - Zoom %
        hwndChild = GetWindow(hwndChild, GW_HWNDNEXT)        'Find the next window handle - Page No.
        'Can use PostMessage instead if wanted
        Call SendMessage(hwndChild, WM_SETTEXT, 0&, lPage)        'Enter our page number into the Adobe Reader Page number textbox
        Call SendMessage(hwndChild, WM_KEYDOWN, VK_RETURN, 0)        'Submit an Enter key to actually switch to the input page
        Call SendMessage(hwndChild, WM_KEYUP, VK_RETURN, 0)
    End If

Error_Handler_Exit:
    On Error Resume Next
    Exit Function

Error_Handler:
    MsgBox "The following error has occurred" & vbCrLf & vbCrLf & _
           "Error Number: " & Err.Number & vbCrLf & _
           "Error Source: ChangePDFPage" & vbCrLf & _
           "Error Description: " & Err.Description & _
           Switch(Erl = 0, "", Erl <> 0, vbCrLf & "Line No: " & Erl) _
           , vbOKOnly + vbCritical, "An Error has Occurred!"
    Resume Error_Handler_Exit
End Function

but around that are all the APIs and other procedures. So look over the demo db provided below for the complete solution.

The other beauty about this code is that although my sample is in Access (my workhorse of choice), it isn’t Access specific, so you can port it into whatever VBA application you need it in (Excel, PowerPoint, Word, …).

I should also mention the above was specifically developed for Adobe Acrobat Reader DC and hasn’t been tested on any other versions.

Disclaimer/Notes:

Microsoft Access 2010 Runtime
Microsoft Access 2013 Runtime
Microsoft Access 2016 Runtime
Microsoft 365 Access Runtime

Download a Demo Database

Feel free to download a 100% unlocked demo copy by using the link provided below:

Version History

(2018-11-25) Initial Release
V1.0000 (2018-11-26) Glitch identifying main Adobe parent window on first call fixed