It is normally essential to always ensure that Office/Access is up-to-date when troubleshooting problems.  Sadly, over the course of the past new releases of MS Office, Microsoft has made finding the version, service pack level of each application difficult to locate, if possible at all.  Yet looking back at 2003, 2000 it was available at the click of a button!

Microsoft solution is to tell you to use the Program and Features dialog from the Control Panel to get the build number of MS Office.  Now this is not great for a number of reasons, of which:

• Not all users can access the control panel due to security restrictions
• Even if they can, it normally isn’t a good idea to let users go play around in the Control Panel
• Even if they do retrieve this beautiful build number, such as 12.0.6423.0, it means nothing and finding a cross-reference table is next to impossible (unless you are on my site!)

So at the end of the day, what do we do when all we want to know is what version of Access are we dealing with.

Below is a function, which I cannot take credit for and I believe (I could be wrong) that the original author was fellow MVP Tom van Stiphout and that I found a number of years ago while trying to solve this dilemma for myself.  All I have done was update it with values for Access 2007 SP 2 and SP3, 2010 & 2013.

 

Function GetAccessEXEVersion() As String
'Valid for us with Access 2000 or later.
'Original author: Tom van Stiphout (I believe)
'New version information added by Daniel Pineault
 
'SysCmd(715) -> 6606
'Application.Version OR SysCmd(acSysCmdAccessVer) -> 12.0
    On Error Resume Next
    Dim sAccessVerNoNo As String
'    sAccessVerNo = fGetProductVersion(Application.SysCmd(acSysCmdAccessDir) & "msaccess.exe")
    sAccessVerNo = SysCmd(acSysCmdAccessVer) & "." & SysCmd(715)
    Select Case sAccessVerNo
        'Access 2000
        Case "9.0.0.0000" To "9.0.0.2999": GetAccessEXEVersion = "Microsoft Access 2000 - Build:" & sAccessVerNo
        Case "9.0.0.3000" To "9.0.0.3999": GetAccessEXEVersion = "Microsoft Access 2000 SP1 - Build:" & sAccessVerNo
        Case "9.0.0.4000" To "9.0.0.4999": GetAccessEXEVersion = "Microsoft Access 2000 SP2 - Build:" & sAccessVerNo
        Case "9.0.0.6000" To "9.0.0.6999": GetAccessEXEVersion = "Microsoft Access 2000 SP3 - Build:" & sAccessVerNo
        'Access 2002
        Case "10.0.2000.0" To "10.0.2999.9": GetAccessEXEVersion = "Microsoft Access 2002 - Build:" & sAccessVerNo
        Case "10.0.3000.0" To "10.0.3999.9": GetAccessEXEVersion = "Microsoft Access 2002 SP1 - Build:" & sAccessVerNo
        Case "10.0.4000.0" To "10.0.4999.9": GetAccessEXEVersion = "Microsoft Access 2002 SP2 - Build:" & sAccessVerNo
        'Access 2003
        Case "11.0.0000.0" To "11.0.5999.9999": GetAccessEXEVersion = "Microsoft Access 2003 - Build:" & sAccessVerNo
        Case "11.0.6000.0" To "11.0.6999.9999": GetAccessEXEVersion = "Microsoft Access 2003 SP1 - Build:" & sAccessVerNo
        Case "11.0.7000.0" To "11.0.7999.9999": GetAccessEXEVersion = "Microsoft Access 2003 SP2 - Build:" & sAccessVerNo
        Case "11.0.8000.0" To "11.0.8999.9999": GetAccessEXEVersion = "Microsoft Access 2003 SP3 - Build:" & sAccessVerNo
        'Access 2007
        Case "12.0.0000.0" To "12.0.5999.9999": GetAccessEXEVersion = "Microsoft Access 2007 - Build:" & sAccessVerNo
        Case "12.0.6000.0" To "12.0.6422.9999": GetAccessEXEVersion = "Microsoft Access 2007 SP1 - Build:" & sAccessVerNo
        Case "12.0.6423.0" To "12.0.5999.9999": GetAccessEXEVersion = "Microsoft Access 2007 SP2 - Build:" & sAccessVerNo
        'Unable to locate specific build versioning for SP3 - to be validated at a later date.
        '  Hopefully MS will eventually post the info on their website?!
        Case "12.0.6000.0" To "12.0.9999.9999": GetAccessEXEVersion = "Microsoft Access 2007 SP3 - Build:" & sAccessVerNo
        'Access 2010
        Case "14.0.0000.0000" To "14.0.6022.1000": GetAccessEXEVersion = "Microsoft Access 2010 - Build:" & sAccessVerNo
        Case "14.0.6023.1000" To "14.0.7014.9999": GetAccessEXEVersion = "Microsoft Access 2010 SP1 - Build:" & sAccessVerNo
        Case "14.0.7015.1000" To "14.0.9999.9999": GetAccessEXEVersion = "Microsoft Access 2010 SP2 - Build:" & sAccessVerNo
        'Access 2013
        Case "15.0.0000.0000" To "15.0.4569.1505": GetAccessEXEVersion = "Microsoft Access 2013 - Build:" & sAccessVerNo
        Case "15.0.4569.1506" To "15.0.9999.9999": GetAccessEXEVersion = "Microsoft Access 2013 SP1 - Build:" & sAccessVerNo
        'Access 2016
        '   See: https://support.office.com/en-us/article/Version-and-build-numbers-of-update-channel-releases-ae942449-1fca-4484-898b-a933ea23def7#bkmk_byversion
        '   To build a proper sequence for all the 2016 versions!
        Case "16.0.0000.0000" To "16.0.9999.9999": GetAccessEXEVersion = "Microsoft Access 2016 - Build:" & sAccessVerNo
        Case Else: GetAccessEXEVersion = "Unknown Version"
    End Select
    If SysCmd(acSysCmdRuntime) Then GetAccessEXEVersion = GetAccessEXEVersion & " Run-time"
End Function

This function will return a string like:

Microsoft Access 2007 SP3 – Build:12.0.6606

I personally incorporate this within my About form, so the user can pull up such useful information at the click of a button without needing to know anything technical or even exiting the active database. IMHO, the way it should be with ALL MS products, but is no longer!

Software should be simple! Why MS has hidden such important information, which used to be so easily accessible, I will never understand! Oh well, at least we can come up with a solution.

Getting the Full Version Information

As pointed out by Andrew Reed (in the comments below) the above does not return the full application version number. So I quickly put together the following to get the full version information for any application registered in the registry. So all Office Application, and more. So if you truly need those last 4 digits, this should do the trick.

'---------------------------------------------------------------------------------------
' Procedure : GetVerInfo
' Author    : Daniel Pineault, CARDA Consultants Inc.
' Website   : http://www.cardaconsultants.com
' Purpose   : Get the FULL file version of an application (Access, Excel, Word, ...)
' Copyright : The following is release as Attribution-ShareAlike 4.0 International
'             (CC BY-SA 4.0) - https://creativecommons.org/licenses/by-sa/4.0/
' Req'd Refs: Uses Late Binding, so none required
'
' Input Variables:
' ~~~~~~~~~~~~~~~~
' sExe      : The EXE file to check
'               Accesss -> msaccess.exe
'               Excel -> excel.exe
'               Word -> Winword.exe
'
' Usage:
' ~~~~~~
' MsgBox GetVerInfo("excel.exe")
'   Returns: 15.0.5007.1000
' sVer = GetVerInfo("msaccess.exe")
'   Returns: 15.0.4963.1000
'
' Revision History:
' Rev       Date(yyyy/mm/dd)        Description
' **************************************************************************************
' 1         2018-02-13              Initial Release
'---------------------------------------------------------------------------------------
Function GetVerInfo(sExe As String)
    On Error GoTo Error_Handler
    Dim oWSHShell             As Object
    Dim oFSO                  As Object     'Scripting.FileSystemObject
    Dim sExePath              As String

    Set oWSHShell = CreateObject("WScript.Shell")
    sExePath = oWSHShell.RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\" & sExe & "\")
    Set oFSO = CreateObject("Scripting.FileSystemObject")
    GetVerInfo = oFSO.GetFileVersion(sExePath)

Error_Handler_Exit:
    On Error Resume Next
    If Not oFSO Is Nothing Then Set oFSO = Nothing
    If Not oWSHShell Is Nothing Then Set oWSHShell = Nothing
    Exit Function

Error_Handler:
    MsgBox "The following error has occurred" & vbCrLf & vbCrLf & _
           "Error Number: " & Err.Number & vbCrLf & _
           "Error Source: GetVerInfo" & vbCrLf & _
           "Error Description: " & Err.Description & _
           Switch(Erl = 0, "", Erl <> 0, vbCrLf & "Line No: " & Erl) _
           , vbOKOnly + vbCritical, "An Error has Occurred!"
    Resume Error_Handler_Exit
End Function