A nice feature to add to any continuous form is the ability to navigate up and down between the records by simply using the keyboard arrow keys. Luckily for us, we have a couple options available to us to make that happen and enhance our user experience.
 

Changing The Client Settings

As pointed out in the comments below, by Jack Perry, as of Access 2019 we now have the ability to add such functionality to a database by changing a database client setting.

File -> Options -> Client Settings
Under the Editing section (at the top), look for the setting entitled Continuous Form Record Navigation Keys and set it to either Up/Down or Left/Right to suit your personal preference.

Remember, this change needs to be made on each user’s PC and as noted previously is only available in newer versions of Microsoft Access. Although I haven’t tried it yet, since this is a database property you should be able to enable it via some simple automation.

I tried locating information on this setting from the official documentation:

sadly, it does not appear! I reported the issue, but have no clue if the Access Dev Team will do any updates to include it.
 

The Coding Approach

Now, simple Google search and we can find the code to add to a form, but I wanted something a little cleaner, a reusable function that I could simply call.  And so taking the typically suggested code, I tweaked it into the following:

'---------------------------------------------------------------------------------------
' Procedure : EnableArrowsScroll
' Author    : Daniel Pineault, CARDA Consultants Inc.
' Website   : http://www.cardaconsultants.com
' Purpose   : Enable using the up and down arrows to move between records on a
'             continuous form
' Req'd Refs: None
' The Form's Key Preview property must be set to True for this code to work.
'
' Input Variables:
' ~~~~~~~~~~~~~~~~
' iKeyCode  : Keycode from the source form from the KeyDown event
' frm       : form object to apply the new behavior to
'
' Usage:
' ~~~~~~
' KeyCode = EnableArrowsScroll(KeyCode, Me) 'This is placed in the KeyDown event
'                            'Dont forget to set the Key Preview property to Yes
'
' Revision History:
' Rev       Date(yyyy/mm/dd)        Description
' **************************************************************************************
' 1         2011-07-07              Initial Release
' 2         2017-04-08              Added DefaultView check
'---------------------------------------------------------------------------------------
Public Function EnableArrowsScroll(ByVal iKeyCode As Integer, frm As Access.Form) As Integer
    On Error GoTo Error_Handler

    If frm.DefaultView = 1 Then    'Only process for Continuous forms
        Select Case iKeyCode
            Case vbKeyDown
                '            If CurrentRecord <> RecordsetClone.RecordCount Then 'Restrict to existing records
                If frm.NewRecord = False Then    'Allow going to new record for data entry
                    DoCmd.GoToRecord , , acNext
                End If
                EnableArrowsScroll = 0
            Case vbKeyUp
                If frm.CurrentRecord <> 1 Then
                    DoCmd.GoToRecord , , acPrevious
                End If
                EnableArrowsScroll = 0
            Case Else
                EnableArrowsScroll = iKeyCode
        End Select
    Else
        EnableArrowsScroll = iKeyCode
    End If

Error_Handler_Exit:
    On Error Resume Next
    If Not frm Is Nothing Then Set frm = Nothing
    Exit Function

Error_Handler:
    If Err.Number <> 2105 Then
        MsgBox "The following error has occurred" & vbCrLf & vbCrLf & _
               "Error Number: " & Err.Number & vbCrLf & _
               "Error Source: EnableArrowsScroll" & vbCrLf & _
               "Error Description: " & Err.Description & _
               Switch(Erl = 0, "", Erl <> 0, vbCrLf & "Line No: " & Erl) _
               , vbOKOnly + vbCritical, "An Error has Occurred!"
    End If
    Resume Error_Handler_Exit
End Function

Then we can call the above with a single line of code in any Form’s On Key Down event, like:

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
    On Error GoTo Error_Handler

    KeyCode = EnableArrowsScroll(KeyCode, Me)

Error_Handler_Exit:
    On Error Resume Next
    Exit Sub

Error_Handler:
    MsgBox "The following error has occurred" & vbCrLf & vbCrLf & _
           "Error Number: " & Err.Number & vbCrLf & _
           "Error Source: Form_KeyDown" & vbCrLf & _
           "Error Description: " & Err.Description & _
           Switch(Erl = 0, "", Erl <> 0, vbCrLf & "Line No: " & Erl) _
           , vbOKOnly + vbCritical, "An Error has Occurred!"
    Resume Error_Handler_Exit
End Sub

The last thing to remember to note, is for the above code to work properly, you must set the form’s Key Preview property to Yes.