Archive for June 23rd, 2010

June 23rd, 2010

What happened to Microsoft’s Newgroups/Forum

Many, Many, Many people have been asking what happened to Microsoft’s Discussion groups that used to be found at http://www.microsoft.com/office/community/en-us/default.mspx.

Sadly, in their infinite (or is that finite) wisdom, Microsoft terminated those groups which had been around for decades and replace it with their ‘new’ and ‘improved’ forums found at http://social.answers.microsoft.com/Forums/en-US/group/Office.

 

Why the Dismay?

There are a number of reasons why I am discontent with this migration move.

  • One of the greatest problems is that they didn’t migrate, but rather shutdown and moved. Which means everything that was previously done, just disappeared over night. You can’t go and look up old posts….
  • If you are an MS Access forum user, then you’ll be disgusted with the simple fact that not only did we loose our categories (forms, queries, reports,…), but Access has been thrown into a common group with Visio and InfoPath… While Excel,… and others retained their own groups, Access has been simply tossed in with numerous other applications? If this is the importance that Microsoft places on its own software, then no wonder users are turning to alternate forums.
  • Another disappointing aspect of the new forum is simply that not all the functionalities actually work (Insert Code for instance). It seems like it was implemented before it was properly tested. Furthermore, months after flagging certain issues, nothing has been fixed!?
  • And then there are all the minor annoyances, such as:
    • If you are on a post and click on the reply button (when you aren’t signed in yet), sign in, you do not get returned to the post you were wanting to reply to… This worked in the old forum. Why in …. name couldn’t they make it work in the new ‘improved’ one!?
    • Sometimes, when you choose to edit a post, the post goes blank!? Your previous post content disappears.

There are many more reasons, but in reality there is no point going on as MS will not change a thing it does. That said, it is because of this that the vast majority of users have simply opted to migrate to alternative groups such as UtterAccess, Yahoo, …

MS’s reasoning, from what I understood, was they wanted to revive their groups, but in fact, from my experience, the numbers have been dropping since their ‘improvement’. The simple fact is that Microsoft chose to ignore the input of countless users, MVPS; the people that use and promote their software. To me it makes no sense! They have no one to blame but themselves for the decline in usage and migration to alternative forums.

CategoryGeneral Technology Discussion | CommentNo Comments »

June 23rd, 2010

VBScript – Create/Set Trusted Location Using VBScript

I looked high and low and had an impossible time, when I needed it, to locate an example, or explanation, of how I could create a Trusted Location for Access, Excel, Word,… using a simple vbscript.

If you manually make an entry in the Trusted Locations and then inspect your registry, you’ll see something similar to the following image (in this case for MS Access, but the same principal applies to almost all MS Office applications)MS Office Trusted Location Registry Keys

As you can see, each application: Access, Excel, PowerPoint, Word as its own Trusted Locations and every entry has a parent key entitled ‘LocationX’, where X is an incremental number. From what I have read (not confirmed in any way) you can have 0 through 19 Trusted Location, so Location0, Location1, …, Location19. With this information in mind and a lot of web searching and vbscripting, I eventually managed to piece a script together and below is what it looks like.

'*******************************************************************************
' Purpose    :Setup the required trusted location
' Author    : Daniel Pineault, CARDA Consultants Inc.
' Website   : http://www.cardaconsultants.com
' Copyright : The following may be altered and reused as you wish so long as the
'             copyright notice is left unchanged (including Author, Website and
'             Copyright).  It may not be sold/resold or reposted on other sites (links
'             back to this site are allowed).
'
'Revision:	2010-06-23   Initial Release
'*******************************************************************************

	Const HKEY_CURRENT_USER = &H80000001
 
	Dim oRegistry	
	Dim sPath			'Path to set as a Trusted Location	
	Dim sDescription		'Description of the Trusted Location
	Dim bAllowSubFolders		'Enable subFolders as Trusted Locations
	Dim bAllowNetworkLocations 	'Enable Network Locations as Trusted
					'	Locations
	Dim bAlreadyExists
	Dim sParentKey
	Dim iLocCounter
	Dim arrChildKeys
	Dim sChildKey	
	Dim sValue
	Dim sNewKey
 
 
'Determine the location/path of the user's MyDocuments folder
'*******************************************************************************
	Set oRegistry = GetObject("winmgmts:\\.\root\default:StdRegProv")
	sPath = "TheFullPathOfYourTrustedLocation" 	'ie: c:\databases\
	sDescription = "YourTrustedLocationDescriptionGoesHere"
	bAllowSubFolders = True
	bAlreadyExists = False
 
	sParentKey = "Software\Microsoft\Office\12.0\Access\Security\Trusted Locations"
'	sParentKey = "Software\Microsoft\Office\12.0\Excel\Security\Trusted Locations"
'	sParentKey = "Software\Microsoft\Office\12.0\PowerPoint\Security\Trusted Locations"
'	sParentKey = "Software\Microsoft\Office\12.0\Word\Security\Trusted Locations"
	iLocCounter = 0
	oRegistry.EnumKey HKEY_CURRENT_USER, sParentKey, arrChildKeys
	For Each sChildKey in arrChildKeys
		oRegistry.GetStringValue HKEY_CURRENT_USER, sParentKey & "\" & sChildKey, "Description", sValue
 		If sValue = sDescription Then bAlreadyExists = True
 
		If CInt(Mid(sChildKey, 9)) > iLocCounter Then
        		iLocCounter = CInt(Mid(sChildKey, 9))
	        End If
	Next
 
'Uncomment the following 4 linesif your wish to enable network locations as Trusted
'	Locations
'	bAllowNetworkLocations = True
'	If bAllowNetworkLocations Then
'    		oRegistry.SetDWORDValue HKEY_CURRENT_USER, sParentKey, "AllowNetworkLocations", 1
'	End If

	If bAlreadyExists = False Then
		sNewKey = sParentKey & "\Location" & CStr(iLocCounter + 1)
 
		oRegistry.CreateKey HKEY_CURRENT_USER, sNewKey
		oRegistry.SetStringValue HKEY_CURRENT_USER, sNewKey, "Path", sPath
		oRegistry.SetStringValue HKEY_CURRENT_USER, sNewKey, "Description", sDescription
 
		If bAllowSubFolders Then
			oRegistry.SetDWORDValue HKEY_CURRENT_USER, sNewKey, "AllowSubFolders", 1
		End If
	End if

As usual when dealing with code off the net, and especially with registry coding, use it at your own risk! I assume no liability whatsoever. I am simply sharing information on what worked for me in the hopes it might help someone else.

CategoryMS Access, MS Office | CommentNo Comments »

Tags: